*!* dian s 2005 especially 4 u - dari solution vfp
*!* thanks tuk mas hambud yg memberikanku semangat scr tdk langsung
*!* tuk menampilkan sample ini
*!* peringatan pemerintah : ini hanya untuk VFP8 dan minimal Win 2000
LOCAL odForm as Form

odForm=CREATEOBJECT('dianFORM')
odForm.Show(1)
READ EVENTS 

DEFINE CLASS dianFORM as Form
autocenter=.t.
backcolor=RGB(236,233,216)
height=400
width=750
Caption="Segala yg transparan selalu menggoda hati :)"
showwindow=2     && As Top Level PERHATIKAN INI !! agar bisa transparan

ADD OBJECT label1 as label WITH ;
Top = 10, ;
Left = 15, ;
Autosize=.t.,;
FontBold=.t.,;
Fontsize=30,;
Forecolor=RGB(255,0,0),;
Caption="HATI-HATI ADA PENAMPAKAN :)"

PROCEDURE init 
**declarekan ini dulu
DECLARE SetWindowLong In Win32Api AS _Sol_SetWindowLong Integer, Integer, Integer
DECLARE SetLayeredWindowAttributes In Win32Api AS _Sol_SetLayeredWindowAttributes Integer, String, Integer, Integer

_Sol_SetWindowLong(this.hWnd, -20, 0x00080000)
_Sol_SetLayeredWindowAttributes(this.hWnd, 0, 255, 2)

ENDPROC

PROCEDURE Destroy
**jo lali tuk clear DLLs yg tadi di declare
CLEAR DLLS _Sol_SetWindowLong
CLEAR DLLS _Sol_SetLayeredWindowAttributes
ENDPROC 

ADD OBJECT keluar AS commandbutton WITH ;
Top = 260, ;
Left = 500, ;
Height = 30, ;
Width = 80, ;
Caption = "\<Close"

ADD OBJECT aksi AS commandbutton WITH ;
Top = 260, ;
Left = 50, ;
Height = 30, ;
Width = 80, ;
Caption = "\<Action"

ADD OBJECT spinner1 AS spinner WITH ;
Increment=10,;
KeyboardHighValue=255,;
KeyboardLowValue=10,;
SpinnerHighValue=255.0,;
SpinnerLowValue=10.0,;
Value=50,;
Top = 220, ;
Left = 50, ;
Height = 30, ;
Width = 60

PROCEDURE keluar.Click
CLEAR EVENTS 
Thisform.release
ENDPROC

PROCEDURE aksi.Click
tipisnya = this.Parent.spinner1.value
_Sol_SetLayeredWindowAttributes(this.Parent.hWnd, 0, tipisnya, 2)
ENDPROC
ENDDEFINE