** mztolo 2007 
** baca file xls dan update ke mysql (sql pass through) :) 
SET MULTILOCKS ON
set century on
set date DMY
s=[Driver={Microsoft Excel Driver (*.xls)};DriverId=790;Dbq=G:\pgw.xls;DefaultDir=G:\;]
n=SQLSTRINGCONNECT(s)
=SQLEXEC(n,'select nip,nama,gaji,tgllahir from [Sheet1$]',[anu])
BROWSE TITLE "hasil select masih dlm bentuk memo..."   && perhatikan field nip,nama, tgllahir

select TRANSFORM(nip) nip,TRANSFORM(nama) nama,gaji,TTOD(tgllahir) tgllahir from anu INTO CURSOR abc
BROWSE TITLE "hasil transform field memo menghasilkan data sebenarnya..."   && perhatikan data sudah rapi

lcDB ='Driver={MySQL ODBC 3.51 Driver};Server=guzrud;Database=coba; User=root;Password=root;Option=3;'
x=SQLSTRINGCONNECT(lcDB)
=SQLEXEC(x,[select nip,nama,gaji,tgllahir from t_pgw],[cRemote])
BROWSE TITLE "mySQL sebelom di update..."

SELECT cRemote
CURSORSETPROP("Buffering",5)
CURSORSETPROP("Tables","t_pgw")
CURSORSETPROP("KeyFieldList","nip")
CURSORSETPROP("UpdatableFieldList","nip,nama,gaji,tgllahir")
CURSORSETPROP("UpdateNameList","nip t_pgw.nip,nama t_pgw.nama,gaji t_pgw.gaji,tgllahir t_pgw.tgllahir")
CURSORSETPROP("SendUpdates",.t.)

APPEND FROM DBF('abc')
a=TABLEUPDATE(.t.,.t.)
IF a=.f.
	**karena kode yg sama, coba dg data yg berkode beda  
	MESSAGEBOX('Update Gagal !',48,'http://mztolo.irenk.com')
ENDIF 

=SQLEXEC(x,[select nip,nama,gaji,tgllahir from t_pgw],[cHasil])
BROWSE TITLE "mySQL setelah di update..."